New.

contrib/crossrpms/acinclude.m4

@@ -0,0 +1,20 @@
+AC_DEFUN([RTEMS_ENABLE_RPMPREFIX],[
+AC_ARG_ENABLE([rpmprefix],
+[  --enable-rpmprefix=<rpmprefix>      prefix rpms],
+[case $enable_rpmprefix in
+yes ) rpmprefix="rtems-"]RTEMS_API["-";;
+no ) rpmprefix="";;
+* ) AS_IF([test -z "$enable_rpmprefix"],
+      [rpmprefix=""],
+      [rpmprefix="$enable_rpmprefix"]);;
+esac],
+[rpmprefix="rtems-"]RTEMS_API["-"])
+
+AC_ARG_ENABLE([osversions],
+[  --enable-osversions       whether to use version numbers in os-tripples],
+[case $enable_osversions in
+yes ) osversion=RTEMS_API;;
+* ) osversion=;;
+esac],
+[osversion=RTEMS_API])
+])

contrib/crossrpms/bootstrap

@@ -0,0 +1,2 @@
+#!/bin/sh
+autoreconf -fis

contrib/crossrpms/configure.ac

@@ -0,0 +1,37 @@
+## $Id$
+
+AC_PREREQ(2.59)
+AC_INIT([crossbuild],[0.20060211.0],[rtems-bugs@rtems.com])
+AC_CONFIG_SRCDIR([binutils/binutils.add])
+AC_CONFIG_AUX_DIR(.)
+
+AM_INIT_AUTOMAKE([no-define foreign 1.9])
+
+AC_CANONICAL_HOST
+
+RTEMS_ENABLE_RPMPREFIX
+
+AC_MSG_CHECKING(for RPM OS)
+case "$host" in
+  i?86-*cygwin*) 	RPM_OS=cygwin ;;
+  i?86-*mingw*)		RPM_OS=mingw32 ;;
+  sparc-*solaris*)	RPM_OS=solaris2.7 ;;
+  i?86-*freebsd5*)	RPM_OS=freebsd5.2 ;;
+  i?86-*freebsd*)	RPM_OS=freebsd6.0 ;;
+  *)
+    AC_MSG_ERROR([Unsupported host ${host}])
+    ;;
+esac
+AC_MSG_RESULT($RPM_OS)
+AC_SUBST(RPM_OS)
+
+AC_CONFIG_FILES([Makefile])
+
+AC_CONFIG_FILES([cygwin/Makefile])
+AC_CONFIG_FILES([mingw32/Makefile])
+AC_CONFIG_FILES([solaris2.7/Makefile])
+AC_CONFIG_FILES([freebsd5.2/Makefile])
+AC_CONFIG_FILES([freebsd6.0/Makefile])
+AC_CONFIG_FILES([rtems/Makefile])
+
+AC_OUTPUT