mirror of
https://github.com/TinyCC/tinycc.git
synced 2025-11-16 12:34:45 +00:00
deb7a3fc73
tcc.c: - be nice to leak checkers tcctools.c: - remove unused TCCState params tccrun.c: - call bound_exit() after signals to let it free mem tccelf.c: - use section_add() instead of section_ptr_add() when more appropriate tccpp.c: - use size_t to align tal_header naturally - 'POINTER_SIZE' and 'PTR_SIZE' in the same source is confusing - "char file_name[TAL_DEBUG_FILE_LEN + 1];" looks silly. - next_nomacro(): skip UTF8 BOM at BOF tccgen.c: - get rid of STMT_EXPR clause on top of block - warn with useless type like 'int;' - move skip()'s in block() for better error line-info - BIT_SIZE bits are meaningful only with VT_BITFIELD (not with enums for example) workflow/test-win32: - build with MSVC using build-tcc.bat also alloca.S: - fix 'off by one' problem on win32 (must touch current page too because the 'push %edx' at the end could touch the next page) - must not align greater than 4 when used for struct args (i386-gen.c:gfunc_call()) libtcc.c: - accept -g1dwarf (dwarf output, only line info)
86 lines
1.3 KiB
ArmAsm
86 lines
1.3 KiB
ArmAsm
/* ---------------------------------------------- */
|
|
/* alloca.S */
|
|
|
|
#ifdef __leading_underscore
|
|
# define _(s) _##s
|
|
#else
|
|
# define _(s) s
|
|
#endif
|
|
|
|
/* ---------------------------------------------- */
|
|
#if defined __i386__
|
|
|
|
.globl _(alloca), _(__alloca)
|
|
_(alloca):
|
|
_(__alloca):
|
|
pop %edx
|
|
pop %eax
|
|
add $3,%eax
|
|
and $-4,%eax
|
|
jz p3
|
|
|
|
#ifdef _WIN32
|
|
p1:
|
|
cmp $4096,%eax
|
|
jb p2
|
|
test %eax,-4096(%esp)
|
|
sub $4096,%esp
|
|
sub $4096,%eax
|
|
jmp p1
|
|
p2:
|
|
#endif
|
|
sub %eax,%esp
|
|
mov %esp,%eax
|
|
p3:
|
|
push %edx
|
|
push %edx
|
|
ret
|
|
|
|
/* ---------------------------------------------- */
|
|
#elif defined __x86_64__
|
|
|
|
.globl _(alloca)
|
|
_(alloca):
|
|
pop %rdx
|
|
#ifdef _WIN32
|
|
mov %rcx,%rax
|
|
#else
|
|
mov %rdi,%rax
|
|
#endif
|
|
add $15,%rax
|
|
and $-16,%rax
|
|
jz p3
|
|
|
|
#ifdef _WIN32
|
|
p1:
|
|
cmp $4096,%rax
|
|
jb p2
|
|
test %rax,-4096(%rsp)
|
|
sub $4096,%rsp
|
|
sub $4096,%rax
|
|
jmp p1
|
|
p2:
|
|
#endif
|
|
sub %rax,%rsp
|
|
mov %rsp,%rax
|
|
p3:
|
|
push %rdx
|
|
ret
|
|
|
|
/* ---------------------------------------------- */
|
|
#elif defined __arm__
|
|
|
|
.text
|
|
.align 2
|
|
.global alloca
|
|
.type alloca, %function
|
|
alloca:
|
|
rsb sp, r0, sp
|
|
bic sp, sp, #7
|
|
mov r0, sp
|
|
mov pc, lr
|
|
.size alloca, .-alloca
|
|
|
|
/* ---------------------------------------------- */
|
|
#endif
|