mirror of
https://gitlab.rtems.org/rtems/rtos/rtems.git
synced 2025-12-06 07:33:17 +00:00
ba748523d1
* configure.ac: Reworked for multilibs, reflect changes to aclocal/*.m4. * aclocal/subdirs.m4: New file. * aclocal/multi.m4: New file, adopted from autoconf-2.52 w/ modifications. * aclocal/check-posix.m4: Apply AS_IF. * aclocal/config-subdirs.m4: Reflect changes to other m4-macros. * aclocal/env-rtemsbsp.m4: Add PROJECT_INCLUDE, PROJECT_RELEASE. Add AM_CONDITIONAL(MULTILIB). Adapt GCC_SPECS to multilibs. * aclocal/env-rtemscpu.m4: Remove RTEMS_BSP. Add support for MULTIBUILDTOP, MULTISUBDIR. Adapt GCC_SPECS to multilibs. Add PROJECT_INCLUDE, PROJECT_RELEASE, includedir, libdir. * aclocal/multilib.m4: Fix m4-quoting, adopt automake-1.5's OUTPUT_COMMANDS. * aclocal/project-root.m4: Remove PROJECT_INCLUDE, PROJECT_RELEASE. * aclocal/rtems-debug.m4: Minor cleanups. * aclocal/rtems-top.m4: Minor cleanups. * automake/compile.am: Further steps towards automake's rules.
60 lines
1.6 KiB
Plaintext
60 lines
1.6 KiB
Plaintext
dnl This provides configure definitions used for multilib support
|
|
|
|
dnl parts of these macros are derived from newlib-1.8.2's multilib support
|
|
|
|
AC_DEFUN(RTEMS_ENABLE_MULTILIB,
|
|
[
|
|
AC_ARG_ENABLE(multilib,
|
|
AC_HELP_STRING([--enable-multilib],
|
|
[build many library versions (default=no)]),
|
|
[case "${enableval}" in
|
|
yes) multilib=yes ;;
|
|
no) multilib=no ;;
|
|
*) AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
|
|
esac], [multilib=no])dnl
|
|
|
|
AM_CONDITIONAL(MULTILIB,test x"${multilib}" = x"yes")
|
|
])
|
|
|
|
AC_DEFUN([RTEMS_ENABLE_MULTILIB_MASTER],
|
|
[
|
|
AC_REQUIRE([RTEMS_ENABLE_MULTILIB])
|
|
|
|
dnl We may get other options which we don't document:
|
|
dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
|
|
|
|
if test "[$]{srcdir}" = "."; then
|
|
if test "[$]{with_target_subdir}" != "."; then
|
|
multilib_basedir="[$]{srcdir}/[$]{with_multisrctop}../ifelse([$2],,,[$2])"
|
|
else
|
|
multilib_basedir="[$]{srcdir}/[$]{with_multisrctop}ifelse([$2],,,[$2])"
|
|
fi
|
|
else
|
|
multilib_basedir="[$]{srcdir}/ifelse([$2],,,[$2])"
|
|
fi
|
|
AC_SUBST(multilib_basedir)
|
|
|
|
if test "${multilib}" = "yes"; then
|
|
multilib_arg="--enable-multilib"
|
|
else
|
|
multilib_arg=
|
|
fi
|
|
|
|
AC_OUTPUT_COMMANDS(
|
|
[case " $CONFIG_FILES " in
|
|
*" ]m4_if([$1],,Makefile,[$1])[ "*)
|
|
ac_file=]m4_if([$1],,Makefile,[$1])[ . ${multilib_basedir}/config-ml.in
|
|
esac],
|
|
[
|
|
srcdir=${srcdir}
|
|
host=${host}
|
|
target=${target}
|
|
with_multisrctop="${with_multisrctop}"
|
|
with_target_subdir="${with_target_subdir}"
|
|
with_multisubdir="${with_multisubdir}"
|
|
ac_configure_args="${multilib_arg} ${ac_configure_args}"
|
|
CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
|
|
multilib_basedir=${multilib_basedir}
|
|
CC="${CC}"])
|
|
])
|