Towards automake VIII patch from Ralf Corsepius <corsepiu@faw.uni-ulm.de>:

OK, I 've made up my mind to cut a big chunk of my automake-patches (:-).

    Below you can find a drop-in replacement of the aclocal directory. It
    contains a lot of new macro files, most of them are directly cut from rtems
    top-level configure script, some are new some are identical to former
    versions. The motivation behind these files is to reuse parts from rtems
    current top-level configure.in script in up-coming subdirectory configure.in
    scripts.

    I'd like to ask you to untar the archive ontop of the source tree and to
    add/commit these files to CVS. Adding these files should not have any
    influence on RTEMS momentary configuration (except of you are required to
    run aclocal -I aclocal && autoconf afterwards), because most of them
    currently are not used at all.

    ---------

    BTW: Please upgrade to autoconf-2.13 and automake-2.4, if you havn't done
    this already (egcs/CVS require them, too). My upcoming automake files
    require automake-2.4 which requires autoconf-2.13 or later.

aclocal.m4

@@ -1,4 +1,27 @@
-dnl aclocal.m4 generated automatically by aclocal 1.2
+dnl aclocal.m4 generated automatically by aclocal 1.4
+
+dnl Copyright (C) 1994, 1995-8, 1999 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This program is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
+dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
+dnl PARTICULAR PURPOSE.
+
+dnl $Id$
+
+AC_DEFUN(RTEMS_PATH_PERL,
+[
+AC_PATH_PROG(PERL,perl)
+if test -z "$PERL" ; then
+AC_MSG_WARN(
+[***]
+[   perl was not found]
+[   Note: Some tools will not be built.])
+fi
+])
 
 dnl
 dnl $Id$
@@ -42,21 +65,61 @@ AC_MSG_RESULT($rtems_cv_prog_MKDIR_M)
 ])
 
 
+dnl $Id$
+
+AC_DEFUN(RTEMS_PATH_KSH,
+[
+dnl NOTE: prefer bash over ksh over sh
+AC_PATH_PROGS(KSH,bash ksh sh)
+if test -z "$KSH"; then
+dnl NOTE: This cannot happen -- /bin/sh must always exist
+AC_MSG_ERROR(
+[***]
+[    Cannot determine a usable shell bash/ksh/sh]
+[    Please contact your system administrator] );
+fi
+])
+
 dnl
 dnl $Id$
 dnl
 
-dnl canonicalize target name
+dnl canonicalize target cpu
 dnl NOTE: Most rtems targets do not fullfil autoconf's
 dnl target naming conventions "processor-vendor-os"
 dnl Therefore autoconf's AC_CANONICAL_TARGET will fail for them
 dnl and we have to fix it for rtems ourselves 
 
 AC_DEFUN(RTEMS_CANONICAL_TARGET_CPU,
-[AC_MSG_CHECKING(rtems target cpu)
+[
-changequote(<<, >>)dnl
+AC_REQUIRE([AC_CANONICAL_SYSTEM])
-target_cpu=`echo $target | sed 's%^\([^-]*\)-\(.*\)$%\1%'`
+AC_MSG_CHECKING(rtems target cpu)
-changequote([, ])dnl
+changequote(,)dnl
+case "${target}" in
+  # hpux unix port should go here
+  i[3456]86-go32-rtems*)
+	target_cpu=i386
+	;;
+  i[3456]86-pc-linux*)		# unix "simulator" port
+	target_cpu=unix
+	;;
+  i[3456]86-*freebsd2*) 	# unix "simulator" port
+	target_cpu=unix
+	;;
+  no_cpu-*rtems*)
+        target_cpu=no_cpu
+	;;
+  ppc*-*rtems*)
+	target_cpu=powerpc
+	;;
+  sparc-sun-solaris*)           # unix "simulator" port
+	target_cpu=unix
+	;;
+  *) 
+	target_cpu=`echo $target | sed 's%^\([^-]*\)-\(.*\)$%\1%'`
+	;;
+esac
+changequote([,])dnl
 AC_MSG_RESULT($target_cpu)
 ])
 

aclocal/canonical-host.m4

@@ -0,0 +1,29 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_CANONICAL_HOST,
+[dnl
+AC_REQUIRE([AC_CANONICAL_HOST])
+RTEMS_HOST=$host_os
+changequote(,)dnl
+case "${target}" in
+  # hpux unix port should go here
+  i[3456]86-go32-rtems*)
+	rtems_bsp="go32 go32_p5"
+       	skip_startfiles="yes"
+	;;
+  i[3456]86-pc-linux*)         # unix "simulator" port
+        RTEMS_HOST=Linux
+	;;
+  i[3456]86-*freebsd2*) # unix "simulator" port
+        RTEMS_HOST=FreeBSD
+	;;
+  sparc-sun-solaris*)             # unix "simulator" port
+        RTEMS_HOST=Solaris
+	;;
+  *) 
+	;;
+esac
+changequote([,])dnl
+AC_SUBST(RTEMS_HOST)
+])dnl
+

aclocal/check-cpu.m4

@@ -0,0 +1,16 @@
+dnl $Id$
+
+dnl check if RTEMS support a cpu
+AC_DEFUN(RTEMS_CHECK_CPU,
+[dnl
+AC_REQUIRE([RTEMS_TOP])
+AC_REQUIRE([RTEMS_CANONICAL_TARGET_CPU])
+# Is this a supported CPU?
+AC_MSG_CHECKING([if cpu $target_cpu is supported])
+if test -d "$srcdir/$RTEMS_TOPdir/c/src/exec/score/cpu/$target_cpu"; then
+  AC_MSG_RESULT(yes)
+else
+  AC_MSG_ERROR(no)
+fi
+])dnl
+

aclocal/enable-bare.m4

@@ -0,0 +1,21 @@
+AC_DEFUN(RTEMS_ENABLE_BARE,
+[
+AC_ARG_ENABLE(bare-cpu-cflags,
+[  --enable-bare-cpu-cflags             specify a particular cpu cflag]
+[                                       (bare bsp specific)],
+[case "${enableval}" in
+  no) BARE_CPU_CFLAGS="" ;;
+  *)    BARE_CPU_CFLAGS="${enableval}" ;;
+esac],
+[BARE_CPU_CFLAGS=""])
+
+AC_ARG_ENABLE(bare-cpu-model,
+[  --enable-bare-cpu-model              specify a particular cpu model]
+[                                       (bare bsp specific)],
+[case "${enableval}" in
+  no)   BARE_CPU_MODEL="" ;;
+  *)    BARE_CPU_MODEL="${enableval}" ;;
+esac],
+[BARE_CPU_MODEL=""])
+])
+

aclocal/enable-cxx.m4

@@ -0,0 +1,13 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_CXX,
+[
+AC_ARG_ENABLE(cxx,
+[  --enable-cxx                         enable C++ support,]
+[                                       and build the rtems++ library],
+[case "${enableval}" in
+  yes) RTEMS_HAS_CPLUSPLUS=yes ;;
+  no) RTEMS_HAS_CPLUSPLUS=no   ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-cxx option) ;;
+esac], [RTEMS_HAS_CPLUSPLUS=no])
+])

aclocal/enable-gcc28.m4

@@ -0,0 +1,12 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_GCC28,
+[
+AC_ARG_ENABLE(gcc28,
+[  --enable-gcc28                       enable use of gcc 2.8.x features],
+[case "${enableval}" in
+  yes) RTEMS_USE_GCC272=no ;;
+  no) RTEMS_USE_GCC272=yes ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for gcc-28 option) ;;
+esac],[RTEMS_USE_GCC272=no])
+])

aclocal/enable-gmake-print.m4

@@ -0,0 +1,15 @@
+dnl $Id$
+dnl
+dnl Note: This option is considered obsolete
+
+AC_DEFUN(RTEMS_ENABLE_GMAKE_PRINT,
+[
+AC_ARG_ENABLE(gmake-print-directory,
+[  --enable-gmake-print-directory       enable GNU Make's print directory],
+[case "${enableval}" in 
+  yes) RTEMS_USE_OWN_PDIR=no ;;
+  no) RTEMS_USE_OWN_PDIR=yes ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for gmake-print-directory option)
+;;
+esac],[RTEMS_USE_OWN_PDIR=yes])
+])

aclocal/enable-hwapi.m4

@@ -0,0 +1,14 @@
+dnl $Id$
+dnl
+dnl FIXME: this needs to be reworked
+
+AC_DEFUN(RTEMS_ENABLE_HWAPI,
+[dnl
+AC_ARG_ENABLE(hwapi, \
+[  --enable-hwapi                       enable hardware API library],
+[case "${enableval}" in
+    yes) RTEMS_HAS_HWAPI=yes ;;
+    no)  RTEMS_HAS_HWAPI=no ;;
+    *)  AC_MSG_ERROR(bad value ${enableval} for hwapi option) ;;
+  esac],[RTEMS_HAS_HWAPI=no])
+])dnl

aclocal/enable-inlines.m4

@@ -0,0 +1,12 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_INLINES,
+[AC_ARG_ENABLE(rtems-inlines,
+[  --enable-rtems-inlines               enable RTEMS inline functions]
+[                                       (use macros)],
+[case "${enableval}" in
+  yes) RTEMS_USE_MACROS=no ;;
+  no) RTEMS_USE_MACROS=yes ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for disable-rtems-inlines option) ;;
+esac],[RTEMS_USE_MACROS=no])
+])

aclocal/enable-libcdir.m4

@@ -0,0 +1,9 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_LIBCDIR,
+[
+AC_ARG_ENABLE(libcdir,
+[  --enable-libcdir=directory           set the directory for the C library],
+[ RTEMS_LIBC_DIR="${enableval}" ; \
+test -d ${enableval} || AC_MSG_ERROR("$enableval is not a directory" ) ] )
+])

aclocal/enable-multiprocessing.m4

@@ -0,0 +1,12 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_MULTIPROCESSING,
+[
+AC_ARG_ENABLE(multiprocessing,
+[  --enable-multiprocessing             enable multiprocessing interface],
+[case "${enableval}" in 
+  yes) RTEMS_HAS_MULTIPROCESSING=yes ;;
+  no) RTEMS_HAS_MULTIPROCESSING=no ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-multiprocessing option) ;;
+esac],[RTEMS_HAS_MULTIPROCESSING=no])
+])

aclocal/enable-networking.m4

@@ -0,0 +1,12 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_NETWORKING,
+[
+AC_ARG_ENABLE(networking,
+[  --enable-networking                  enable TCP/IP stack],
+[case "${enableval}" in
+  yes) RTEMS_HAS_NETWORKING=yes ;;
+  no) RTEMS_HAS_NETWORKING=no ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-networking option) ;;
+esac],[RTEMS_HAS_NETWORKING=yes])
+])

aclocal/enable-posix.m4

@@ -0,0 +1,36 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_POSIX,
+[
+AC_ARG_ENABLE(posix,
+[  --enable-posix                       enable posix interface],
+[case "${enableval}" in 
+  yes) RTEMS_HAS_POSIX_API=yes ;;
+  no) RTEMS_HAS_POSIX_API=no ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-posix option) ;;
+esac],[RTEMS_HAS_POSIX_API=yes]) 
+
+changequote(,)dnl
+case "${target}" in
+  # hpux unix port should go here
+  i[3456]86-go32-rtems*)
+	RTEMS_HAS_POSIX_API=no
+	;;
+  i[3456]86-pc-linux*)         # unix "simulator" port
+	RTEMS_HAS_POSIX_API=no
+	;;
+  i[3456]86-*freebsd2*) # unix "simulator" port
+	RTEMS_HAS_POSIX_API=no
+	;;
+  no_cpu-*rtems*)
+	RTEMS_HAS_POSIX_API=no
+	;;
+  sparc-sun-solaris*)             # unix "simulator" port
+	RTEMS_HAS_POSIX_API=no
+	;;
+  *) 
+	;;
+esac
+changequote([,])dnl
+AC_SUBST(RTEMS_HAS_POSIX_API)
+])

aclocal/enable-rdbg.m4

@@ -0,0 +1,12 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_RDBG,
+[
+AC_ARG_ENABLE(rdbg,
+[  --enable-rdbg                        enable remote debugger],
+[case "${enableval}" in
+  yes) RTEMS_HAS_RDBG=yes ;;
+  no) RTEMS_HAS_RDBG=no ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-rdbg option) ;;
+esac],[RTEMS_HAS_RDBG=no])
+])

aclocal/enable-tests.m4

@@ -0,0 +1,15 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_ENABLE_TESTS,
+[
+# If the tests are enabled, then find all the test suite Makefiles
+AC_MSG_CHECKING([if the test suites are enabled? ])
+tests_enabled=yes
+AC_ARG_ENABLE(tests,
+[  --enable-tests                       enable tests (default:disabled)],
+  [case "${enableval}" in
+    yes) AC_MSG_RESULT(yes) ;;
+    no)  AC_MSG_RESULT(no) ; tests_enabled=no ;;
+    *)   AC_MSG_ERROR(bad value ${enableval} for tests option) ;;
+  esac], AC_MSG_RESULT(no))
+])

aclocal/rtems-top.m4

@@ -0,0 +1,13 @@
+dnl $Id$
+
+AC_DEFUN(RTEMS_TOP,
+[dnl
+RTEMS_TOPdir="$1";
+AC_SUBST(RTEMS_TOPdir)
+
+PROJECT_ROOT=`pwd`/$RTEMS_TOPdir;
+AC_SUBST(PROJECT_ROOT)
+
+RTEMS_ROOT='$(top_srcdir)'/$RTEMS_TOPdir;
+AC_SUBST(RTEMS_ROOT)
+])dnl

aclocal/tool-paths.m4

@@ -0,0 +1,16 @@
+AC_DEFUN(RTEMS_TOOLPATHS,
+[
+# tooldir='$(exec_prefix)/'$target_alias
+# Temporary work-around until building in source tree is supported
+tooldir='$(PROJECT_ROOT)'
+AC_SUBST(tooldir)
+
+project_includedir='$(tooldir)'/include
+AC_SUBST(project_includedir)
+
+project_libdir='$(tooldir)/lib$(MULTISUBDIR)'
+AC_SUBST(project_libdir)
+
+project_bindir='$(tooldir)/bin'
+AC_SUBST(project_bindir)
+])