Imagelibrary/rtems-patmos
1
0
Fork 0
mirror of https://github.com/t-crest/rtems.git synced 2025-11-16 12:34:47 +00:00
Code Issues Packages Projects Releases Wiki Activity

2003-08-21 Ralf Corsepius <corsepiu@faw.uni-ulm.de>

Browse Source 
* aclocal/bsp-arg-enable.m4, aclocal/bsp-configure.m4,
	aclocal/bspopts.m4, aclocal/canonicalize-tools.m4,
	aclocal/check-bsp-cache.m4, aclocal/check-cxx.m4,
	aclocal/check-itron.m4, aclocal/check-multiprocessing.m4,
	aclocal/check-networking.m4, aclocal/check-newlib.m4,
	aclocal/check-posix.m4, aclocal/check-rdbg.m4,
	aclocal/check-tool.m4, aclocal/env-rtemsbsp.m4,
	aclocal/gcc-isystem.m4, aclocal/gcc-pipe.m4,
	aclocal/gcc-specs.m4, aclocal/i386-gas-code16.m4,
	aclocal/path-perl.m4, aclocal/ppc.m4,
	aclocal/prog-cc.m4, aclocal/prog-ccas.m4,
	aclocal/prog-cxx.m4, aclocal/prog-gnat.m4,
	aclocal/rtems-debug.m4, aclocal/rtems-flags.m4,
	aclocal/rtems-test-no-pause.m4, aclocal/target.m4:
	Remove (Unused).
	* automake/leaf.am, automake/force-preinstall.am:
	Remove (Unused).
	* Makefile.am: Reflect changes above.
This commit is contained in:
Ralf Corsepius
2003-08-21 05:37:41 +00:00
parent fb7f8d35bf
commit 8ad16bac29
32 changed files with 56 additions and 1024 deletions
Download Patch File Download Diff File Expand all files Collapse all files

21
ChangeLog
View File

@@ -1,3 +1,24 @@
2003-08-21 Ralf Corsepius <corsepiu@faw.uni-ulm.de>
* aclocal/bsp-arg-enable.m4, aclocal/bsp-configure.m4,
aclocal/bspopts.m4, aclocal/canonicalize-tools.m4,
aclocal/check-bsp-cache.m4, aclocal/check-cxx.m4,
aclocal/check-itron.m4, aclocal/check-multiprocessing.m4,
aclocal/check-networking.m4, aclocal/check-newlib.m4,
aclocal/check-posix.m4, aclocal/check-rdbg.m4,
aclocal/check-tool.m4, aclocal/env-rtemsbsp.m4,
aclocal/gcc-isystem.m4, aclocal/gcc-pipe.m4,
aclocal/gcc-specs.m4, aclocal/i386-gas-code16.m4,
aclocal/path-perl.m4, aclocal/ppc.m4,
aclocal/prog-cc.m4, aclocal/prog-ccas.m4,
aclocal/prog-cxx.m4, aclocal/prog-gnat.m4,
aclocal/rtems-debug.m4, aclocal/rtems-flags.m4,
aclocal/rtems-test-no-pause.m4, aclocal/target.m4:
Remove (Unused).
* automake/leaf.am, automake/force-preinstall.am:
Remove (Unused).
* Makefile.am: Reflect changes above.
2003-08-17 Ralf Corsepius <corsepiu@faw.uni-ulm.de>
* automake/local.am, automake/host.am: Remove "debug".

56
Makefile.am
View File

@@ -10,32 +10,46 @@ ACLOCAL_AMFLAGS = -I aclocal
SUBDIRS = make $(build_SUBDIRS) $(host_SUBDIRS) $(target_SUBDIRS)
AUTOMAKE_FILES = automake/compile.am automake/host.am automake/lib.am \
automake/local.am automake/subdirs.am \
automake/leaf.am automake/force-preinstall.am
AUTOMAKE_FILES =
AUTOMAKE_FILES += automake/compile.am
AUTOMAKE_FILES += automake/host.am
AUTOMAKE_FILES += automake/local.am
AUTOMAKE_FILES += automake/subdirs.am
ACLOCAL_FILES = aclocal/bsp-alias.m4 aclocal/canonical-host.m4 \
aclocal/canonical-target-name.m4 aclocal/canonicalize-tools.m4 \
aclocal/check-bsp-cache.m4 aclocal/check-bsps.m4 aclocal/check-cpu.m4 \
aclocal/check-cxx.m4 aclocal/check-itron.m4 \
aclocal/check-multiprocessing.m4 aclocal/check-networking.m4 \
aclocal/check-newlib.m4 aclocal/check-posix.m4 aclocal/check-rdbg.m4 \
aclocal/enable-bare.m4 aclocal/enable-cxx.m4 \
aclocal/enable-inlines.m4 aclocal/enable-itron.m4 \
aclocal/enable-multiprocessing.m4 aclocal/enable-networking.m4 \
aclocal/enable-posix.m4 aclocal/enable-rdbg.m4 aclocal/enable-rtemsbsp.m4 \
aclocal/enable-tests.m4 aclocal/gcc-pipe.m4 aclocal/gcc-specs.m4 \
aclocal/i386-gas-code16.m4 aclocal/multilib.m4 aclocal/path-ksh.m4 \
aclocal/path-perl.m4 aclocal/prog-cc.m4 aclocal/prog-cxx.m4 \
aclocal/project-root.m4 aclocal/rtems-debug.m4 \
aclocal/rtems-test-no-pause.m4 aclocal/rtems-top.m4 \
aclocal/target.m4 aclocal/tool-paths.m4 aclocal/bspopts.m4 \
aclocal/ppc.m4 aclocal/bsp-configure.m4 aclocal/gcc-isystem.m4
ACLOCAL_FILES =
ACLOCAL_FILES += bsp-alias.m4
ACLOCAL_FILES += canonical-host.m4
ACLOCAL_FILES += canonical-target-name.m4
ACLOCAL_FILES += check-bsps.m4
ACLOCAL_FILES += check-cpu.m4
ACLOCAL_FILES += check-custom-bsp.m4
ACLOCAL_FILES += config-subdirs.m4
ACLOCAL_FILES += enable-bare.m4
ACLOCAL_FILES += enable-cxx.m4
ACLOCAL_FILES += enable-inlines.m4
ACLOCAL_FILES += enable-itron.m4
ACLOCAL_FILES += enable-multiprocessing.m4
ACLOCAL_FILES += enable-networking.m4
ACLOCAL_FILES += enable-posix.m4
ACLOCAL_FILES += enable-rdbg.m4
ACLOCAL_FILES += enable-rtemsbsp.m4
ACLOCAL_FILES += enable-rtems-debug.m4
ACLOCAL_FILES += enable-tests.m4
ACLOCAL_FILES += multilib.m4
ACLOCAL_FILES += path-ksh.m4
ACLOCAL_FILES += project-root.m4
ACLOCAL_FILES += quoting.m4
ACLOCAL_FILES += rtems-cpu-subdirs.m4
ACLOCAL_FILES += rtems-top.m4
ACLOCAL_FILES += tool-paths.m4
ACLOCAL_FILES += version.m4
noinst_SCRIPTS = bootstrap
EXTRA_DIST = $(AUTOMAKE_FILES) $(ACLOCAL_FILES) README.configure SUPPORT \
EXTRA_DIST = README.configure SUPPORT \
VERSION LICENSE $(noinst_SCRIPTS)
EXTRA_DIST += $(AUTOMAKE_FILES)
EXTRA_DIST += $(ACLOCAL_FILES)
include $(top_srcdir)/automake/subdirs.am
include $(top_srcdir)/automake/host.am

18
aclocal/bsp-arg-enable.m4
View File

@@ -1,18 +0,0 @@
dnl $Id$
dnl
dnl RTEMS_BSP_ARG_ENABLE(FEATURE, HELP-STRING, ACTION-IF-TRUE [, ACTION-IF-FALSE])
dnl
dnl Accept --enable-FEATURE=<RTEMS_BSP>:<bsp-value> and
dnl --enable-FEATURE=<value> in BSP-configure scripts.
dnl
dnl Configure scripts will receive <bsp-value> if <RTEMS_BSP> matches the
dnl actual value of the shell variable RTEMS_BSP (cf. RTEMS_ENV_RTEMSBSP),
dnl and the raw value passed to --enable-FEATURE otherwise.
dnl
AC_DEFUN(RTEMS_BSP_ARG_ENABLE,
[AC_REQUIRE([RTEMS_ENV_RTEMSBSP])
AC_ARG_ENABLE([$1],[$2],
[enableval=`echo "[$enable_]patsubst([$1], -, _)" | sed -e "s%^${RTEMS_BSP}:%%"`
eval "[enable_]patsubst([$1], -, _)='$enableval'"
$3],[$4])
])

35
aclocal/bsp-configure.m4
View File

@@ -1,35 +0,0 @@
dnl $Id$
dnl RTEMS_BSP_CONFIGURE
dnl Common macro to be included by all bsp-configure.acs
AC_DEFUN([RTEMS_BSP_CONFIGURE],
[
AC_PREREQ([2.52])
AM_MAINTAINER_MODE
RTEMS_ENV_RTEMSBSP
RTEMS_CHECK_CUSTOM_BSP(RTEMS_BSP)
RTEMS_CANONICAL_HOST
AM_CONFIG_HEADER([include/bspopts.tmp:include/bspopts.h.in],[
echo "/* BSP dependent options file */" >$tmp/config.h
echo "/* automatically generated -- DO NOT EDIT!! */" >>$tmp/config.h
echo >>$tmp/config.h
echo "#ifndef __BSP_OPTIONS_h" >>$tmp/config.h
echo "#define __BSP_OPTIONS_h" >>$tmp/config.h
echo >>$tmp/config.h
sed -e '/.*PACKAGE.*/d' include/bspopts.tmp >> $tmp/config.h
echo >>$tmp/config.h
echo "#endif" >>$tmp/config.h
AS_IF([cmp -s include/bspopts.h $tmp/config.h 2>/dev/null],[
AC_MSG_NOTICE([include/bspopts.h is unchanged])
rm -f $tmp/config.h],[
AC_MSG_NOTICE([creating include/bspopts.h])
rm -f include/bspopts.h
mv $tmp/config.h include/bspopts.h
])
])
RTEMS_PROJECT_ROOT
RTEMS_CHECK_MULTIPROCESSING
])

66
aclocal/bspopts.m4
View File

@@ -1,66 +0,0 @@
dnl $Id$
dnl
dnl RTEMS_BSPOPTS_* - some autoconf voodoo to handle default values and
dnl help-strings for per-BSP-environment variables.
dnl To be used in bsp-configure scripts
dnl Example:
dnl
dnl RTEMS_BSPOPTS_SET([foo],[bar],[0])
dnl RTEMS_BSPOPTS_SET([foo],[baz*],[hello])
dnl RTEMS_BSPOPTS_SET([foo],[*],[])
dnl RTEMS_BSPOPTS_HELP([foo],[env. variable foo])
dnl -> Add "0" as default value of variable "foo" for BSP "bar"
dnl -> Add "hello" as default value of variable "foo" for all BSPs starting
dnl with "baz" in their name.
dnl -> Undefine foo as default clause for all BSP's.
dnl
dnl All this basically expands to a /bin/shell "case"-statement with
dnl accompanying autoconf magic to propagate VAR to bspopts.h.
dnl RTEMS_BSPOPTS_HELP(VAR,HELP-STRING)
dnl Set up printing the HELP-STRING for bspopts.h's variable VAR and add
dnl appropriate /bin/sh-magic to "configure" to have VAR set up.
AC_DEFUN([RTEMS_BSPOPTS_HELP],[
RTEMS_ARG_VAR([$1],[$2])
m4_ifdef([_$1],[
case ${RTEMS_BSP} in
_$1[]dnl
esac],[])
if test -n "[$]{$1}"; then[]dnl
AC_DEFINE_UNQUOTED([$1],
[[$]$1],
[$2])dnl
fi
])
dnl RTEMS_BSPOPTS_SET(VAR,BSP,DEFAULT)
dnl Set up a value DEFAULT to be used as default value for variable VAR for
dnl BSP in RTEMS_BSPOPTS_HELP.
dnl MUST be use in front of exactly _one_ corresponding RTEMS_BSPOPTS_HELP
AC_DEFUN([RTEMS_BSPOPTS_SET],[dnl
m4_append([_$1],
[$2 )
$1=[$]{$1-$3} ;;
])
])
dnl RTEMS_ARG_VAR(VAR,HELP-STRING)
dnl An internal macros to have RTEMS_BSPOPTS_HELP's help string pretty
dnl printed with configure --help.
dnl Stripped down version of autoconf-2.52's AC_ARG_VAR.
AC_DEFUN([RTEMS_ARG_VAR],
[
m4_expand_once([m4_divert_once([HELP_VAR],
[AC_HELP_STRING([$1], [$2], [ ])])],
[$0($1)])dnl
])

23
aclocal/canonicalize-tools.m4
View File

@@ -1,23 +0,0 @@
dnl
dnl $Id$
dnl
dnl Set target tools
dnl
AC_DEFUN(RTEMS_CANONICALIZE_TOOLS,
[AC_REQUIRE([RTEMS_PROG_CC])dnl
dnl FIXME: What shall be done if these tools are not available?
RTEMS_CHECK_TOOL(AR,ar,no)
RTEMS_CHECK_TOOL(AS,as,no)
RTEMS_CHECK_TOOL(LD,ld,no)
RTEMS_CHECK_TOOL(NM,nm,no)
dnl special treatment of ranlib
RTEMS_CHECK_TOOL(RANLIB,ranlib,:)
dnl NOTE: These may not be available if not using gnutools
RTEMS_CHECK_TOOL(OBJCOPY,objcopy,no)
RTEMS_CHECK_TOOL(SIZE,size,no)
RTEMS_CHECK_TOOL(STRIP,strip,:)
])

34
aclocal/check-bsp-cache.m4
View File

@@ -1,34 +0,0 @@
dnl $Id$
dnl RTEMS_CHECK_BSP_CACHE(RTEMS_BSP)
AC_DEFUN([RTEMS_CHECK_BSP_CACHE],
[
AC_REQUIRE([RTEMS_CHECK_CPU])dnl sets RTEMS_CPU, target
AC_REQUIRE([RTEMS_ENV_RTEMSBSP])dnl set RTEMS_BSP
AC_REQUIRE([RTEMS_TOP])dnl sets RTEMS_TOPdir
AC_CACHE_CHECK([for RTEMS_CPU_MODEL], [rtems_cv_RTEMS_CPU_MODEL],
[. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache])
RTEMS_CPU_MODEL=$rtems_cv_RTEMS_CPU_MODEL
AC_SUBST(RTEMS_CPU_MODEL)
AC_CACHE_CHECK([for RTEMS_BSP_FAMILY],[rtems_cv_RTEMS_BSP_FAMILY],
[. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache])
RTEMS_BSP_FAMILY=$rtems_cv_RTEMS_BSP_FAMILY
AC_SUBST(RTEMS_BSP_FAMILY)
AC_CACHE_CHECK([for RTEMS_BSP_CFLAGS],[rtems_cv_RTEMS_BSP_CFLAGS],
[. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache])
RTEMS_BSP_CFLAGS=$rtems_cv_RTEMS_BSP_CFLAGS
AC_SUBST(RTEMS_BSP_CFLAGS)
AC_CACHE_CHECK([for RTEMS_BSP_CFLAGS_OPTIMIZE_V],[rtems_cv_RTEMS_BSP_CFLAGS_OPTIMIZE_V],
[. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache])
RTEMS_BSP_CFLAGS_OPTIMIZE_V=$rtems_cv_RTEMS_BSP_CFLAGS_OPTIMIZE_V
AC_SUBST(RTEMS_BSP_CFLAGS_OPTIMIZE_V)
AC_CACHE_CHECK([for RTEMS_BSP_CFLAGS_DEBUG_V],[rtems_cv_RTEMS_BSP_CFLAGS_DEBUG_V],
[. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache])
RTEMS_BSP_CFLAGS_DEBUG_V=$rtems_cv_RTEMS_BSP_CFLAGS_DEBUG_V
AC_SUBST(RTEMS_BSP_CFLAGS_DEBUG_V)
])

26
aclocal/check-cxx.m4
View File

@@ -1,26 +0,0 @@
dnl $Id$
dnl
AC_DEFUN(RTEMS_CHECK_CXX,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_PROG_CC_FOR_TARGET])dnl
AC_REQUIRE([RTEMS_PROG_CXX_FOR_TARGET])dnl
AC_CACHE_CHECK([whether to build rtems++],
rtems_cv_HAS_CPLUSPLUS,
[ if test "$RTEMS_HAS_CPLUSPLUS" = "yes"; then
if test -n "$CXX"; then
rtems_cv_HAS_CPLUSPLUS="yes"
else
rtems_cv_HAS_CPLUSPLUS="no"
fi
else
rtems_cv_HAS_CPLUSPLUS="no"
fi])
HAS_CPLUSPLUS="$rtems_cv_HAS_CPLUSPLUS";
AC_SUBST(HAS_CPLUSPLUS)dnl
if test "$HAS_CPLUSPLUS" = "yes"; then
CPLUS_LD_LIBS='$(PROJECT_RELEASE)/lib/librtems++$(LIB_VARIANT).a'
fi
AC_SUBST(CPLUS_LD_LIBS)
])

37
aclocal/check-itron.m4
View File

@@ -1,37 +0,0 @@
dnl $Id$
dnl
AC_DEFUN(RTEMS_CHECK_ITRON_API,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_ITRON])dnl
AC_CACHE_CHECK([whether CPU supports libitron],
rtems_cv_HAS_ITRON_API,
[dnl
case "$RTEMS_CPU" in
unix*)
rtems_cv_HAS_ITRON_API="no"
;;
*)
if test "${RTEMS_HAS_ITRON_API}" = "yes"; then
rtems_cv_HAS_ITRON_API="yes";
else
rtems_cv_HAS_ITRON_API="disabled";
fi
;;
esac])
if test "$rtems_cv_HAS_ITRON_API" = "yes"; then
HAS_ITRON_API="yes";
else
HAS_ITRON_API="no";
fi
AC_SUBST(HAS_ITRON_API)dnl
])
AC_DEFUN(RTEMS_DEFINE_ITRON_API,
[AC_REQUIRE([RTEMS_CHECK_ITRON_API])dnl
if test x"${HAS_ITRON_API}" = x"yes";
then
AC_DEFINE_UNQUOTED(RTEMS_ITRON_API,1,[if itron api is supported])
fi
])

42
aclocal/check-multiprocessing.m4
View File

@@ -1,42 +0,0 @@
dnl
dnl $Id$
dnl
AC_DEFUN(RTEMS_CHECK_MULTIPROCESSING,
[dnl
AC_REQUIRE([RTEMS_ENABLE_MULTILIB])dnl
AC_REQUIRE([RTEMS_ENV_RTEMSBSP])dnl
AC_REQUIRE([RTEMS_TOP])dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_MULTIPROCESSING])dnl
AC_REQUIRE([RTEMS_BSP_ALIAS])dnl
AC_CACHE_CHECK([if wanting multiprocessing],
[rtems_cv_want_multiprocessing],
[
AS_IF([test x"$multilib" = x"no"],
[# no cpukit
rtems_cv_want_multiprocessing="$enable_multiprocessing"
],[
#HACK: Should check for RTEMS_MULTIPROCESSING in cpuopts.h, instead
rtems_cv_want_multiprocessing="$enable_multiprocessing"
])
])
AS_IF([test "$rtems_cv_want_multiprocessing" = "yes"],
[
AC_CACHE_CHECK([whether BSP supports multiprocessing],
[rtems_cv_HAS_MP],[
if test -d "$srcdir/${RTEMS_TOPdir}/c/src/lib/libbsp/${RTEMS_CPU}/${RTEMS_BSP_FAMILY}/shmsupp"; then
rtems_cv_HAS_MP="yes" ;
else
rtems_cv_HAS_MP="no";
fi
])
if test $rtems_cv_HAS_MP = "no"; then
AC_MSG_ERROR([multiprocessing requested but not supported])
fi
],[rtems_cv_HAS_MP="no";])
AC_SUBST(HAS_MP,[$rtems_cv_HAS_MP])
])

29
aclocal/check-networking.m4
View File

@@ -1,29 +0,0 @@
dnl $Id$
dnl
AC_DEFUN(RTEMS_CHECK_NETWORKING,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_NETWORKING])dnl
AC_CACHE_CHECK([whether BSP supports networking],
rtems_cv_HAS_NETWORKING,
[dnl
case "$RTEMS_CPU" in
unix*)
rtems_cv_HAS_NETWORKING="no"
;;
*)
if test "${RTEMS_HAS_NETWORKING}" = "yes"; then
rtems_cv_HAS_NETWORKING="yes";
else
rtems_cv_HAS_NETWORKING="disabled";
fi
;;
esac])
if test "$rtems_cv_HAS_NETWORKING" = "yes"; then
HAS_NETWORKING="yes";
else
HAS_NETWORKING="no";
fi
AC_SUBST(HAS_NETWORKING)dnl
])

30
aclocal/check-newlib.m4
View File

@@ -1,30 +0,0 @@
dnl $Id$
AC_DEFUN(RTEMS_CHECK_NEWLIB,
[dnl
AC_REQUIRE([RTEMS_PROG_CC_FOR_TARGET])dnl
AC_REQUIRE([RTEMS_CANONICALIZE_TOOLS])dnl
AC_CACHE_CHECK([for RTEMS newlib],
rtems_cv_use_newlib,
[
dnl some versions of newlib provide not_required_by_rtems
AC_LINK_IFELSE(
[AC_LANG_PROGRAM([[extern void not_required_by_rtems() ;]],
[[not_required_by_rtems()]])],
[rtems_cv_use_newlib="yes"],[])
dnl some versions of newlib provide rtems_provides_crt0()
AS_IF([test -z "$rtems_cv_use_newlib"],
[AC_LINK_IFELSE(
[AC_LANG_PROGRAM([[extern void rtems_provides_crt0() ;]],
[[rtems_provides_crt0()]])],
[rtems_cv_use_newlib="yes"],[rtems_cv_use_newlib="no"])
])
])
RTEMS_USE_NEWLIB="$rtems_cv_use_newlib"
AC_SUBST(RTEMS_USE_NEWLIB)
AS_IF([test x"${RTEMS_USE_NEWLIB}" = x"yes"],
[ AC_DEFINE_UNQUOTED(RTEMS_NEWLIB,1,[if using newlib])]
)
])

36
aclocal/check-posix.m4
View File

@@ -1,36 +0,0 @@
dnl $Id$
dnl
AC_DEFUN(RTEMS_CHECK_POSIX_API,
[dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_ENABLE_POSIX])dnl
AC_CACHE_CHECK([whether CPU supports libposix],
rtems_cv_HAS_POSIX_API,
[dnl
case "$RTEMS_CPU" in
unix*)
rtems_cv_HAS_POSIX_API="no"
;;
*)
if test "${RTEMS_HAS_POSIX_API}" = "yes"; then
rtems_cv_HAS_POSIX_API="yes";
else
rtems_cv_HAS_POSIX_API="disabled";
fi
;;
esac])
if test "$rtems_cv_HAS_POSIX_API" = "yes"; then
HAS_POSIX_API="yes";
else
HAS_POSIX_API="no";
fi
AC_SUBST(HAS_POSIX_API)dnl
])
AC_DEFUN(RTEMS_DEFINE_POSIX_API,
[AC_REQUIRE([RTEMS_CHECK_POSIX_API])dnl
AS_IF(
[test x"${HAS_POSIX_API}" = x"yes"],
[AC_DEFINE_UNQUOTED(RTEMS_POSIX_API,1,[if posix api is supported])])
])

41
aclocal/check-rdbg.m4
View File

@@ -1,41 +0,0 @@
dnl $Id$
dnl
AC_DEFUN(RTEMS_CHECK_RDBG,
[dnl
AC_REQUIRE([RTEMS_TOP])dnl
AC_REQUIRE([RTEMS_CHECK_CPU])dnl
AC_REQUIRE([RTEMS_CHECK_NETWORKING])dnl
AC_REQUIRE([RTEMS_ENABLE_RDBG])dnl
AC_CACHE_CHECK([whether BSP supports librdbg],
rtems_cv_HAS_RDBG,
[
if test -d "$srcdir/${RTEMS_TOPdir}/c/src/librdbg/src/${RTEMS_CPU}/${$1}";
then
rtems_cv_HAS_RDBG="yes" ;
elif test -d "$srcdir/${RTEMS_TOPdir}/c/src/librdbg/src/${RTEMS_CPU}/any";
then
rtems_cv_HAS_RDBG="yes" ;
elif test "${RTEMS_CPU}" = "powerpc";
then
A=`grep -l RTEMS_PPC_EXCEPTION_PROCESSING_MODEL $srcdir/${RTEMS_TOPdir}/make/custom/* 2>/dev/null`;
C=""
for i in ${A} ;
do
B=`basename ${i} .cfg`;
C="${C} ${B}";
done
rtems_cv_HAS_RDBG="no";
for j in ${C} ;
do
if test "${$1}" = "${j}" ;
then
rtems_cv_HAS_RDBG="yes";
fi
done
else
rtems_cv_HAS_RDBG="no";
fi
])
HAS_RDBG="$rtems_cv_HAS_RDBG"
AC_SUBST(HAS_RDBG)
])

11
aclocal/check-tool.m4
View File

@@ -1,11 +0,0 @@
dnl $Id$
## Check for a cross tool, similar to AC_CHECK_TOOL, but do not fall back to
## the un-prefixed version of PROG-TO-CHECK-FOR.
dnl RTEMS_CHECK_TOOL(VARIABLE, PROG-TO-CHECK-FOR[, VALUE-IF-NOT-FOUND [, PATH]])
AC_DEFUN(RTEMS_CHECK_TOOL,
[
AS_IF([test "x$build_alias" != "x$host_alias"],
[rtems_tool_prefix=${ac_tool_prefix}])
AC_CHECK_PROG($1, ${rtems_tool_prefix}$2, ${rtems_tool_prefix}$2, $3, $4)
])

56
aclocal/env-rtemsbsp.m4
View File

@@ -1,56 +0,0 @@
dnl $Id$
dnl Pass a single BSP via an environment variable
dnl used by per BSP configure scripts
AC_DEFUN(RTEMS_ENV_RTEMSBSP,
[dnl
AC_BEFORE([$0], [RTEMS_ENABLE_RTEMSBSP])dnl
AC_BEFORE([$0], [RTEMS_PROJECT_ROOT])dnl
AC_BEFORE([$0], [RTEMS_CHECK_CUSTOM_BSP])dnl
AC_ARG_VAR([CPU_CFLAGS],[CFLAGS specifying CPU-dependent features])
AC_ARG_VAR([CFLAGS_OPTIMIZE_V],[CFLAGS for building the OPTIMIZE variant])
AC_ARG_VAR([CFLAGS_DEBUG_V],[CFLAGS for building the DEBUG variant])
AC_ARG_VAR([RTEMS_BSP_FAMILY],[RTEMS's BSP directory])
AC_ARG_VAR([RTEMS_CPU_MODEL],[RTEMS's cpu model])
AC_ARG_VAR([RTEMS_BSP],[RTEMS_BSP to build])
AC_MSG_CHECKING([for RTEMS_BSP])
AC_CACHE_VAL(rtems_cv_RTEMS_BSP,
[dnl
test -n "${RTEMS_BSP}" && rtems_cv_RTEMS_BSP="$RTEMS_BSP";
])dnl
if test -z "$rtems_cv_RTEMS_BSP"; then
AC_MSG_ERROR([Missing RTEMS_BSP])
fi
RTEMS_BSP="$rtems_cv_RTEMS_BSP"
AC_MSG_RESULT(${RTEMS_BSP})
AC_SUBST(RTEMS_BSP)
RTEMS_BSP_SPECS="-specs bsp_specs -qrtems"
AC_SUBST(RTEMS_BSP_SPECS)
GCC_SPECS="-B\$(PROJECT_ROOT)/lib/ -B\$(PROJECT_ROOT)/$RTEMS_BSP/lib/"
AC_SUBST(GCC_SPECS)
PROJECT_INCLUDE="\$(PROJECT_ROOT)/$RTEMS_BSP/lib/include"
AC_SUBST(PROJECT_INCLUDE)
PROJECT_RELEASE="\$(PROJECT_ROOT)/$RTEMS_BSP"
AC_SUBST(PROJECT_RELEASE)
RTEMS_ROOT="\$(PROJECT_ROOT)/c/$RTEMS_BSP"
AC_SUBST(RTEMS_ROOT)
RTEMS_ENABLE_BARE
AC_SUBST(BARE_CPU_MODEL)
AC_SUBST(BARE_CPU_CFLAGS)
AM_CONDITIONAL([MULTILIB],[false])
includedir="\${exec_prefix}/${RTEMS_BSP}/lib/include"
libdir="\${exec_prefix}/${RTEMS_BSP}/lib"
bsplibdir="\${exec_prefix}/${RTEMS_BSP}/lib"
AC_SUBST(bsplibdir)
])

25
aclocal/gcc-isystem.m4
View File

@@ -1,25 +0,0 @@
dnl
dnl $Id$
dnl
dnl Check whether the gcc accepts -isystem
dnl
AC_DEFUN(RTEMS_GCC_ISYSTEM,
[AC_REQUIRE([RTEMS_PROG_CC])
AC_CACHE_CHECK(whether $CC accepts -isystem,rtems_cv_gcc_isystem,
[
rtems_cv_gcc_isystem=no
if test x"$GCC" = x"yes"; then
cat << EOF > conftest.h
int conftest123();
EOF
cat << EOF > conftest.c
#include <conftest.h>
int conftest123() {}
EOF
if test -z "`${CC} -isystem./ -c conftest.c 2>&1`";then
rtems_cv_gcc_isystem=yes
fi
fi
rm -f conftest*
])])

21
aclocal/gcc-pipe.m4
View File

@@ -1,21 +0,0 @@
dnl
dnl $Id$
dnl
dnl Check whether the target compiler accepts -pipe
dnl
AC_DEFUN(RTEMS_GCC_PIPE,
[AC_REQUIRE([RTEMS_PROG_CC])
AC_REQUIRE([AC_CANONICAL_HOST])
AC_CACHE_CHECK(whether $CC accepts --pipe,rtems_cv_gcc_pipe,
[
rtems_cv_gcc_pipe=no
if test x"$GCC" = x"yes"; then
echo 'void f(){}' >conftest.c
if test -z "`${CC} --pipe -c conftest.c 2>&1`";then
rtems_cv_gcc_pipe=yes
fi
rm -f conftest*
fi
])
])

20
aclocal/gcc-specs.m4
View File

@@ -1,20 +0,0 @@
dnl
dnl $Id$
dnl
dnl Check whether the target compiler accepts -specs
dnl
AC_DEFUN(RTEMS_GCC_SPECS,
[AC_REQUIRE([RTEMS_PROG_CC])
AC_CACHE_CHECK(whether $CC accepts -specs,rtems_cv_gcc_specs,
[
rtems_cv_gcc_specs=no
if test x"$GCC" = x"yes"; then
touch confspec
echo 'void f(){}' >conftest.c
if test -z "`${CC} -specs confspec -c conftest.c 2>&1`";then
rtems_cv_gcc_specs=yes
fi
fi
rm -f confspec conftest*
])])

31
aclocal/i386-gas-code16.m4
View File

@@ -1,31 +0,0 @@
dnl
dnl $Id$
dnl
dnl check for i386 gas supporting 16 bit mode
dnl - binutils 2.9.1.0.7 and higher
AC_DEFUN(RTEMS_I386_GAS_CODE16,
[ if test "${host_cpu}" = "i386"; then
AC_CACHE_CHECK([for 16 bit mode assembler support],
rtems_cv_prog_gas_code16,
[cat > conftest.s << EOF
.code16
data32
addr32
lgdt 0
EOF
if AC_TRY_COMMAND($AS -o conftest.o conftest.s); then
rtems_cv_prog_gas_code16=yes
else
rtems_cv_prog_gas_code16=no
fi])
RTEMS_GAS_CODE16="$rtems_cv_prog_gas_code16"
fi
AC_SUBST(RTEMS_GAS_CODE16)
if test x"${RTEMS_GAS_CODE16}" = x"yes";
then
AC_DEFINE_UNQUOTED(NEW_GAS,1,[if using 16 bit mode assembler support])
fi
])

12
aclocal/path-perl.m4
View File

@@ -1,12 +0,0 @@
dnl $Id$
AC_DEFUN(RTEMS_PATH_PERL,
[
AC_PATH_PROG(PERL,perl)
if test -z "$PERL" ; then
AC_MSG_WARN(
[***]
[ perl was not found]
[ Note: Some tools will not be built.])
fi
])

87
aclocal/ppc.m4
View File

@@ -1,87 +0,0 @@
# $Id$
#
# Some hacks for handling powerpc-exception subdirectories
#
# Note: Consider this file a temporary band-aid until a better, more general
# subdirectory handling solution is introduced to RTEMS.
AC_DEFUN([RTEMS_PPC_EXCEPTIONS],
[
exceptions="$1_exception_processing"
AC_SUBST(exceptions)
AC_CONFIG_COMMANDS_POST(
[
exceptions_subdirs="$1_exception_processing"
updir=/../support
if test "$no_recursion" != yes; then
RTEMS_CONFIGURE_ARGS_QUOTE([ac_sub_configure_args])
for ac_subdir in : $exceptions_subdirs; do test "x$ac_subdir" = x: && continue
# Do not complain, so a configure script can configure whichever
# parts of a large source tree are present.
test -d $srcdir${updir}/$ac_subdir || continue
AC_MSG_NOTICE([configuring in $ac_subdir])
case $srcdir in
.) ;;
*) AS_MKDIR_P(["./$ac_subdir"])
if test -d ./$ac_subdir; then :;
else
AC_MSG_ERROR([cannot create `pwd`/$ac_subdir])
fi
;;
esac
ac_popdir=`pwd`
cd $ac_subdir
# A "../" for each directory in /$ac_subdir.
ac_dots=`echo $ac_subdir |
sed 's,^\./,,;s,[[^/]]$,&/,;s,[[^/]]*/,../,g'`
case $srcdir in
.) # No --srcdir option. We are building in place.
ac_sub_srcdir=$srcdir${updir} ;;
[[\\/]]* | ?:[[\\/]]* ) # Absolute path.
ac_sub_srcdir=$srcdir${updir}/$ac_subdir ;;
*) # Relative path.
ac_sub_srcdir=$ac_dots$srcdir${updir}/$ac_subdir ;;
esac
# Check for guested configure; otherwise get Cygnus style configure.
if test -f $ac_sub_srcdir/configure.gnu; then
ac_sub_configure="$SHELL '$ac_sub_srcdir/configure.gnu'"
elif test -f $ac_sub_srcdir/configure; then
ac_sub_configure="$SHELL '$ac_sub_srcdir/configure'"
elif test -f $ac_sub_srcdir/configure.in; then
ac_sub_configure=$ac_configure
else
AC_MSG_WARN([no configuration information is in $ac_subdir])
ac_sub_configure=
fi
# The recursion is here.
if test -n "$ac_sub_configure"; then
# Make the cache file name correct relative to the subdirectory.
case $cache_file in
[[\\/]]* | ?:[[\\/]]* ) ac_sub_cache_file=$cache_file ;;
*) # Relative path.
ac_sub_cache_file=$ac_dots$cache_file ;;
esac
AC_MSG_NOTICE([running $ac_sub_configure $ac_sub_configure_args --cache-file=$ac_sub_cache_file --srcdir=$ac_sub_srcdir])
# The eval makes quoting arguments work.
eval $ac_sub_configure $ac_sub_configure_args \
--cache-file=$ac_sub_cache_file --srcdir=$ac_sub_srcdir ||
AC_MSG_ERROR([$ac_sub_configure failed for $ac_subdir])
fi
cd $ac_popdir
done
fi
])
])

48
aclocal/prog-cc.m4
View File

@@ -1,48 +0,0 @@
dnl
dnl $Id$
dnl
dnl Check for target gcc
dnl
AC_DEFUN(RTEMS_PROG_CC,
[
AC_BEFORE([$0], [AC_PROG_CPP])dnl
AC_BEFORE([$0], [AC_PROG_CC])dnl
AC_BEFORE([$0], [RTEMS_CANONICALIZE_TOOLS])dnl
_RTEMS_FLAGS([CFLAGS],
["\$(CPU_CFLAGS) \$(RTEMS_CFLAGS_\$(VARIANT_V)_V) \$(CFLAGS_\$(VARIANT_V)_V) -g"])
RTEMS_CHECK_TOOL(CC,gcc)
test -z "$CC" && \
AC_MSG_ERROR([no acceptable cc found in \$PATH])
AC_PROG_CC
AC_PROG_CPP
AM_CONDITIONAL(RTEMS_USE_GCC,test x"$GCC" = x"yes")
])
AC_DEFUN(RTEMS_PROG_CC_FOR_TARGET,
[
dnl check target cc
RTEMS_PROG_CC
dnl check if the compiler supports -isystem
RTEMS_GCC_ISYSTEM
dnl check if the target compiler may use --pipe
RTEMS_GCC_PIPE
test "$rtems_cv_gcc_pipe" = "yes" && CC="$CC --pipe"
dnl check if the compiler supports --specs
RTEMS_GCC_SPECS
if test "$GCC" = yes; then
RTEMS_CFLAGS="$RTEMS_CFLAGS -Wall"
m4_if([$1],,[],[RTEMS_CFLAGS="$RTEMS_CFLAGS $1"])
fi
AS_IF([test x"$rtems_cv_gcc_isystem" = x"yes"],[
RTEMS_CPPFLAGS="-isystem \$(PROJECT_INCLUDE)"],[
RTEMS_CPPFLAGS="-I\$(PROJECT_INCLUDE)"
])
AC_SUBST(RTEMS_CPPFLAGS)
])

8
aclocal/prog-ccas.m4
View File

@@ -1,8 +0,0 @@
## $Id$
AC_DEFUN([RTEMS_PROG_CCAS],
[
AC_REQUIRE([RTEMS_PROG_CC])
AC_SUBST(CCAS,["$CC \$(GCCSPECS)"])
AC_SUBST(CCASFLAGS,["-DASM \$(CFLAGS) \$(INCLUDES)"])
])

35
aclocal/prog-cxx.m4
View File

@@ -1,35 +0,0 @@
dnl
dnl $Id$
dnl
dnl Check for target g++
dnl
AC_DEFUN(RTEMS_PROG_CXX_FOR_TARGET,
[
AC_BEFORE([$0], [RTEMS_CANONICALIZE_TOOLS])dnl
AC_REQUIRE([RTEMS_ENABLE_CXX])
RTEMS_CHECK_TOOL(CXX,g++)
if test "$RTEMS_HAS_CPLUSPLUS" = "yes";
then
_RTEMS_FLAGS([CXXFLAGS],
["\$(CPU_CFLAGS) \$(RTEMS_CFLAGS_\$(VARIANT_V)_V) \$(CFLAGS_\$(VARIANT_V)_V) -g"])
dnl Only accept g++
dnl NOTE: This might be too restrictive
test -z "$CXX" \
&& AC_MSG_ERROR([no acceptable c++ found in \$PATH])
AC_PROG_CXX
if test "$ac_cv_prog_cc_cross" != "$ac_cv_prog_cxx_cross"; then
AC_MSG_ERROR([***]
[Inconsistency in compiler configuration:]
[Target C compiler and target C++ compiler]
[must both either be cross compilers or native compilers]
[Hint: If building a posix bsp: LD_LIBRARY_PATH?] )
fi
else
## Work-around to a bug in automake
AM_CONDITIONAL([am__fastdepCXX],[false])
fi
])

26
aclocal/prog-gnat.m4
View File

@@ -1,26 +0,0 @@
## $Id$
##
## WARNING: All the stuff below is pretty immature.
AC_DEFUN([RTEMS_PROG_GNAT],
[AC_REQUIRE([AC_CHECK_TOOL_PREFIX])
AC_REQUIRE([RTEMS_PROG_CC_FOR_TARGET])
AC_ARG_VAR([GNATMAKE],[GNATMAKE compiler command])
AC_ARG_VAR([ADAFLAGS],[ADA compiler flags])
RTEMS_CHECK_TOOL([GNATMAKE],[gnatmake],[])
AS_IF([test -z "$GNATMAKE"],[AC_MSG_ERROR([No GNATMAKE found])])
AC_MSG_CHECKING([whether $GNATMAKE works])
rm -f conftest.*
cat >conftest.adb <<EOF
procedure conftest is begin null; end conftest;
EOF
AS_IF([$GNATMAKE -c conftest.adb 1>>config.log 2>&1],
[HAVE_GNAT=yes],
[HAVE_GNAT=no])
AC_MSG_RESULT([$HAVE_GNAT])
rm -f conftest.*
])

19
aclocal/rtems-debug.m4
View File

@@ -1,19 +0,0 @@
## $Id$
AC_DEFUN(RTEMS_ENABLE_RTEMS_DEBUG,
[
AC_ARG_ENABLE(rtems-debug,
AC_HELP_STRING([--enable-rtems-debug],[enable RTEMS_DEBUG]),
[case "${enable_rtems_debug}" in
yes) enable_rtems_debug=yes ;;
no) enable_rtems_debug=no ;;
*) AC_MSG_ERROR([bad value ${enable_rtems_debug} for RTEMS_DEBUG]) ;;
esac],[enable_rtems_debug=no])
])
AC_DEFUN(RTEMS_CHECK_RTEMS_DEBUG,
[AC_REQUIRE([RTEMS_ENABLE_RTEMS_DEBUG])
AS_IF([test x"${enable_rtems_debug}" = x"yes"]
[AC_DEFINE_UNQUOTED(RTEMS_DEBUG,1,[if RTEMS_DEBUG is enabled])])
])

11
aclocal/rtems-flags.m4
View File

@@ -1,11 +0,0 @@
## $Id$
##
## Some hacks to set up RTEMS_*FLAGS
## Internal macro, not supposed to be explictly used in configure.ac's
AC_DEFUN([_RTEMS_FLAGS],[
AS_IF([test -n "[$]{$1}"],
[RTEMS_$1=[$]{$1}],
[RTEMS_$1=$2])
AC_SUBST([RTEMS_$1])
])

18
aclocal/rtems-test-no-pause.m4
View File

@@ -1,18 +0,0 @@
AC_DEFUN(RTEMS_ENABLE_RTEMS_TEST_NO_PAUSE,
[AC_ARG_ENABLE(test-no-pause,
AC_HELP_STRING([--disable-test-no-pause],[disable RTEMS_TEST_NO_PAUSE]),
[case "${enableval}" in
yes) RTEMS_TEST_NO_PAUSE=yes ;;
no) RTEMS_TEST_NO_PAUSE=no ;;
*) AC_MSG_ERROR([bad value ${enableval} for RTEMS_TEST_NO_PAUSE]) ;;
esac],[RTEMS_TEST_NO_PAUSE=yes])
])
AC_DEFUN(RTEMS_CHECK_RTEMS_TEST_NO_PAUSE,
[AC_REQUIRE([RTEMS_ENABLE_RTEMS_TEST_NO_PAUSE])
if test x"${RTEMS_TEST_NO_PAUSE}" = x"yes";
then
AC_DEFINE_UNQUOTED(RTEMS_TEST_NO_PAUSE,1,[if RTEMS_TEST_NO_PAUSE is enabled])
fi
])

138
aclocal/target.m4
View File

@@ -1,138 +0,0 @@
dnl $Id$
## HACK: Work-around to structural issue with RTEMS
## The macros below violate most autoconf and canonicalization standards
AC_DEFUN(RTEMS_CONFIG_BUILD_SUBDIRS,
[AC_REQUIRE([_RTEMS_OUTPUT_BUILD_SUBDIRS])
RTEMS_BUILD_SUBDIRS="$RTEMS_BUILD_SUBDIRS [$1]"
])
dnl Derived from automake-1.4's AC_OUTPUT_SUBDIRS
AC_DEFUN([_RTEMS_OUTPUT_BUILD_SUBDIRS],
[AC_CONFIG_COMMANDS([bsp-tools],
[
# HACK: This is a blantant hack and breaks Canadian crosses
build_alias="$build_alias"
host_alias="$build_alias"
if test "$no_recursion" != yes; then
if test x"$build_alias" != x"$host_alias"; then
target_subdir="$host_alias"
else
target_subdir="."
fi
RTEMS_CONFIGURE_ARGS_QUOTE([ac_sub_configure_args],
[
-host* | --host* ) ;;
--host ) ac_prev=host_alias;;
-target* | --target* ) ;;
-target ) ac_prev=target_alias ;;
-build* | --build* ) ;;
-build ) ac_prev_build_alias ;;
*_alias=* ) ;; # HACK: Workaround to autoconf passing *_alias
],
[rtems_configure_args])
for rtems_config_dir in $RTEMS_BUILD_SUBDIRS; do
# Do not complain, so a configure script can configure whichever
# parts of a large source tree are present.
if test ! -d $srcdir/$rtems_config_dir; then
continue
fi
_RTEMS_PUSH_BUILDDIR([$rtems_config_dir])
_RTEMS_SUB_SRCDIR([$rtems_config_dir])
# The recursion is here.
if test -n "$ac_sub_configure"; then
# ac_sub_cache_file=./config.cache
ac_sub_cache_file=/dev/null
_RTEMS_GIVEN_INSTALL
echo "[running ${CONFIG_SHELL-/bin/sh} $ac_sub_configure $ac_sub_configure_args --cache-file=$ac_sub_cache_file] --srcdir=$ac_sub_srcdir"
# The eval makes quoting arguments work.
if eval ${CONFIG_SHELL-/bin/sh} $ac_sub_configure \
$ac_sub_configure_args \
--srcdir=$ac_sub_srcdir \
--with-target-subdir=$target_subdir \
--cache-file=$ac_sub_cache_file
then :
else
AC_MSG_ERROR([$ac_sub_configure failed for $rtems_config_dir])
fi
fi
_RTEMS_POP_BUILDDIR
done
fi],
[
RTEMS_BUILD_SUBDIRS="$RTEMS_BUILD_SUBDIRS"
rtems_configure_args="$ac_configure_args"
])
])
## FIXME: This is obsolete. Only kept for backward compatibility
AU_DEFUN([RTEMS_OUTPUT_BUILD_SUBDIRS],[])
dnl
dnl Misc utility macros for subdir handling to work around missing abilities
dnl in autoconf, automake and structural issues with RTEMS
dnl
dnl Contains parts derived from autoconf-2.13 AC_OUTPUT_SUBDIRS and Cygnus'
dnl configure.in.
dnl
dnl
dnl _RTEMS_PUSH_BUILDDIR(SUBDIR)
dnl
AC_DEFUN(_RTEMS_PUSH_BUILDDIR,
[
# _RTEMS_PUSH_BUILDDIR
echo configuring in $1
case "$srcdir" in
.) ;;
*) AS_MKDIR_P([$1])
;;
esac
ac_popdir=`pwd`
cd $1
])
dnl
dnl _RTEMS_POP_BUILDDIR
dnl
AC_DEFUN(_RTEMS_POP_BUILDDIR,
[
cd $ac_popdir
])
dnl
dnl _RTEMS_GIVEN_INSTALL
dnl
AC_DEFUN(_RTEMS_GIVEN_INSTALL,
[
ifdef([AC_PROVIDE_AC_PROG_INSTALL],[
case "$ac_given_INSTALL" in
[[\\/]]* | ?:[[\\/]]*) INSTALL="$ac_given_INSTALL" ;;
*) INSTALL="$ac_dots$ac_given_INSTALL" ;;
esac
])dnl
])
dnl
dnl _RTEMS_SUB_SRCDIR(AC_CONFIG_DIR[,TARGET_SUBDIR])
dnl
AC_DEFUN(_RTEMS_SUB_SRCDIR,[
# _RTEMS_SUB_SRCDIR
_RTEMS_ADJUST_SRCDIR(ac_sub_srcdir,$1,$2)
# Check for configure
if test -f $ac_sub_srcdir/configure; then
ac_sub_configure=$ac_sub_srcdir/configure
else
AC_MSG_WARN([no configuration information is in $1])
ac_sub_configure=
fi
])

4
automake/force-preinstall.am
View File

@@ -1,4 +0,0 @@
## This file is a temporary band-aid for the ppc-BSPs.
## DO NOT use it, it will eventually be removed in future.
PREINSTALL_FILES = $(TMPINSTALL_FILES)

16
automake/leaf.am
View File

@@ -1,16 +0,0 @@
include $(RTEMS_ROOT)/make/leaf.cfg
CXXLINK_APP = $(CXXLINK) $(LDLIBS) $(LINK_OBJS) $(LINK_LIBS)
ifndef make-cxx-exe
define make-cxx-exe
$(CXXLINK_APP)
endef
@ENDIF@
LINK_APP = $(LINK) $(LDLIBS) $(LINK_OBJS) $(LINK_LIBS)
ifndef make-exe
define make-exe
$(LINK_APP)
endef
@ENDIF@